// author: Chris Dragert

commands = {i,n,s,e,w,u,d,look,take,open,eat,sit,sleep,use,focus,shift,talk,ask,free}
place = {Outside, you}
staff = {you}
room you {
	state {resisted, resetResist, outside, porridge, chairs, beds, eatenMatrix, weakened}
	counter {resist 0 4}
}

// To understand the resistance mechanic in act 1, make sure you look at the thread() code
// on line 1092

room Outside {
	label = "Outside";
	(you,look) {
		"You look around, brushing aside a lock of your golden hair. The quaint home ";
		"has a welcoming feel, and seems to be inviting you inside. The side door is";
		"in front of you to the north, while the forest otherwise surrounds you.";
		
		if (you.resist == 3) {
			" ";
			"The world looks different somehow, but nothing stands out.";
		}
	}
	(you,n) {
		"You open the door and move inside.";
		move you from Outside to Kitchen;
		+you.resetResist;
		-you.outside;
		+you.porridge;
	}
	(you,open) {
		"You open the door and move inside.";
		move you from Outside to Kitchen;
		+you.resetResist;
		-you.outside;
		+you.porridge;
	}
	// going s,e,w all resist
	(you,s) {
		"You start to move, but a sudden wave of vertigo overwhelms you.";
		"When you get your bearings, you find yourself still facing the door.";
		+you.resisted;
	}
	(you,e) {
		"You start to move, but a sudden wave of vertigo overwhelms you.";
		"When you get your bearings, you find yourself still facing the door.";
		+you.resisted;
	}
	(you,w) {
		"You start to move, but a sudden wave of vertigo overwhelms you.";
		"When you get your bearings, you find yourself still facing the door.";
		+you.resisted;
	}
}

room Kitchen {
	
	enter {
		"You walk into the kitchen of the home.";
	}
	(you, s) {
		"You considering walking back outside, but the aroma of the porridge is too";
		"delicious. You lose the willpower to move.";
		+you.resisted;
	}
	(you, e) {
		"You leave the porridge and the kitchen behind.";
		if (you.chairs) {
			+you.resetResist;
		}
		else {
			+you.resisted;
		}
		move you from Kitchen to LivingRoom;
	}
	(you, look) {
		"A homely country kitchen lies before you. To the east is the living room.";
		if (you.porridge) {
			"Three delicious bowls of porridge sit in front of you.";
		}
		else {
			"One empty bowl sits here, and two temperature-challenged bowls.";
		}
		if (Kitchen contains spoon) {
			"A large spoon sits beside the bowls";
		}
		if (you.resist == 3) {
			if (Kitchen contains matrix) {
				" ";
				"You don't know how, but the `just right' bowl of porridge now has";
				"a digital overlay, pointing out a device hidden inside.";
			}
			if (you.eatenMatrix) {
				" ";
				"Your belly seems to be glowing with a digital overlay screaming warning";
				"signs. The indication is that this is a serious problem; perhaps you";
				"should pay closer attention to your diet.";
			}
		}
	}
	(you, look, porridge) {
		if (you.porridge) {
			if (you.resist == 3) {
				if (Kitchen contains matrix) {
					"You don't know how, but the `just right' bowl of porridge now has";
					"a digital overlay, pointing out a device hidden inside.";
				}
				else {
					"The porridge looks fine, now that you've removed the device";
				}
			}
			else {
				"The porridge looks a bit strange, but it's still appetizing.";
			}
		}
		else {
			"The hot and cold porridges are still hot and cold.";
		}
	}		
	(you, look, device) {
		if (you.resist == 3) {
			"The overlay indicates the device is a psycho-isolation matrix woven into";
			"the porridge, and that it can be removed.  Eating it would probably be bad.";
		}
		else {
			"What device?";
		}
	}
	(you, take, matrix) {
		if (you.resist == 3) {
			"By gesturing through the overlay, you manage to unweave and take the";
			"psycho-isolation matrix.  It seems strange that you, Goldilocks, know";
			"what a psycho-isolation matrix is.";
			move matrix from Kitchen to you;
			-?matrix.porridge;
		}
		else {
			"What is a matrix?";
		}
	}
	(you, take, spoon) {
		if (you contains spoon) {
			"You already have it.";
		}
		else {
			"You grab the spoon.";
			move spoon from Kitchen to you;
			+you.resetResist;
		}
	}
	(you, take, porridge) {
		"You'd rather eat it.";
	}
	(you, take, bowl) {
		if (Kitchen contains bowl) {
			if (bowl.used) {
				"Not when it's full.";
			}
			else {
				"It's dirty, but that won't stop you.";
				move bowl from Kitchen to you;
			}
		}
		else {
			"You already have the empty bowl.";
		}
	}
	(you,eat) {
		if (you!.porridge) {
			"You don't want the remaining porridge.";
			+you.resisted;
		}		
		else {
			if (you contains spoon) {
				"You try the first bowl of porridge, and it's too hot! The second";
				"is too cold.  The third is just right, and you greedily devour";
				"the entire bowl.";
				if (matrix.porridge) {
					+you.eatenMatrix;
					move matrix from Kitchen to offscreen;
				}
				-bowl.used;
				+you.resetResist;
				-you.porridge;
				+you.chairs;
			}
			else {
				"With your bare hands?";
			}
		}
	}
	// code clone of (you,eat) to accomodate different input
	(you,eat, porridge) {
		if (you!.porridge) {
			"You don't want the remaining porridge.";
			+you.resisted;
		}		
		else {
			if (you contains spoon) {
				"You try the first bowl of porridge, and it's too hot! The second";
				"is too cold.  The third is just right, and you greedily devour";
				"the entire bowl.";
				if (matrix.porridge) {
					+you.eatenMatrix;
					move matrix from Kitchen to offscreen;
				}
				-bowl.used;
				+you.resetResist;
				-you.porridge;
				+you.chairs;
			}
			else {
				"With your bare hands?";
			}
		}
	}
}

room LivingRoom {
	enter {
		"You walk into the living room.";
	}
	(you, w) {
		if (you.porridge) {
			+you.resetResist;
		}
		if (you.chairs) {
			"You're so tired after eating that porridge.  You stumble out of the living room,";
			"longing to return to the chairs.";
			+you.resisted;
		}
		if (you.beds) {
			"You leave the chairs, still tired.  Maybe a bed and a proper sleep can satisfy you.";
			+you.resisted;
		}
		move you from LivingRoom to Kitchen;
	}
	(you, u) {
		if (you.porridge) {
			"You go upstairs, moving farther away from the delicious porridge.";
			+you.resisted;
		}
		if (you.chairs) {
			"You need to rest after eating that porridge.  You stumble out of the living room,";
			"longing to return to the chairs.";
			+you.resisted;
		}
		if (you.beds) {
			"You head upstairs.";
			+you.resetResist;
		}
		move you from LivingRoom to Bedroom;
	}
	(you, n) {
		"You try to head out the front door, but you start to feel very dizzy.";
		"Turning around, you immediately regain your balance.  You decide to stay";
		"in the living room.";
		+you.resisted;
	}
	(you, look) {
		"This is the living room of the house. West is the kitchen, and upstairs is the";
		"bedroom. The home's front door is on the north side of the room.";
		if (you.beds) {
			"The two large chairs are just where you left them, and the third remains";
			"in pieces on the floor.";
		}
		else {
			"There are three chairs in this room.";
		}
		if (you.resist == 3) {
			if (you.eatenMatrix) {
				" ";
				"Your belly seems to be glowing with a digital overlay screaming warning";
				"signs. The indication is that this is a serious problem; perhaps you";
				"should pay closer attention to your diet.";
			}
			if (weakener.chair) {
				" ";
				"A strange digital overlay superimposes itself on your vision, indicating";
				"that the `just right' chair contains a strange device.";
			}
		}
	}
	(you, look, device) {
		if (you.resist == 3) {
			"The overlay indicates that this device is a `weakener'.  When triggered, it";
			"disrupts psionic defenses and weakens mental resistance.";
		}
		else {
			"What device?";
		}
	}
	(you, take, weakener) {
		if (you.resist == 3) {
			"You remove the weakener from the chair.";
			move weakener from LivingRoom to you;
			-weakener.chair;
		}
		else {
			"What is a weakener?";
		} 
	}
	(you, take, pieces) {
		if (you contains chairleg) {
			"The remaining pieces are too small.";
		}
		else {
			"You pick up a broken chair leg.  Even a bear would respect a whack from this.";
			move chairleg from LivingRoom to you;
		}
	}
	(you, sit) {
		if (you.porridge) {
			"You'd rather not.";
			+you.resisted;
		}
		if (you.beds) {
			"You don't like the remaining chairs.";
			+you.resisted;
		}
		if (you.chairs) {
			"You sit in the first chair, but find that it's just too big! The second";
			"chair is also too big. You sit in the third chair. It feels fantastic,";
			"but unfortunately it breaks just after you settle in.";
			move chairleg from offscreen to LivingRoom;
			+you.resetResist;
			-you.chairs;
			+you.beds;
			if (weakener.chair) {
				+you.weakened;
				-weakener.chair;
				move weakener from LivingRoom to offscreen;
			}
		}
	}
}

room Bedroom {
	label = "Bedroom";
	enter {
		"You walk into the bedroom.";
	}
	(you, d) {
		if (you.beds) {
			+you.resisted;
		}
		else {
			+you.resetResist;
		}
		"You head back downstairs.";
		move you from Bedroom to LivingRoom;
	}
	(you, s) {
		"You try to open up the closet, but a violent spell of vertigo";
		"overwhelms your intentions.  You stay in the bedroom.";
		+you.resisted;
	}
	(you, look) {
		"You see three beds arranged across the room. They're all quite";
		"large; each bed is big enough for a bear! There is a closet to the";
		"south, and there are stairs leading to the lower level.";
		if (you.resist == 3) {
			if (you.eatenMatrix) {
				" ";
				"Your belly seems to be glowing with a digital overlay screaming warning";
				"signs. The indication is that this is a serious problem; perhaps you";
				"should pay closer attention to your diet.";
			}
			" ";
			"A digital overlay appears over the smallest bed.  It indicates";
			"that there is a device in the `just right' bed.";
		}
	}
	(you, look, device) {
		if (you.resist == 3) {
			"The device seems to be a trance inducing psychic focuser.  While this is";
			"terrifying to you, your overlay indicates that this could be useful.";
		}
		else {
			"What device?";
		}
	}
	(you, take, focuser) {
		if (you.resist == 3) {
			"You think about detaching the focuser, but your overlay indicates that";
			"your cybernetics can work with this device if you just go to sleep.";
		}
		else {
			"What is a focuser?";
		}
	}
	(you, sleep) {
		if (you!.beds) {
			"You aren't tired.";
			+you.resisted;
		}
		else {
			"Tired from your adventure, you lay down on the biggest bed to sleep.";
			"It's too firm for you to enjoy.  The middle best is too soft, but the";
			"third one is just right.  You lay down your golden locks, and drift to";
			"sleep...";
		
			if (you.eatenMatrix) {
				if (you.weakened) {
					"Dreams come rapidly.  You hear voices speaking,";
					"`She followed along perfectly, acted out the story, completely oblivious!'";
					"Your last memory is a dream about missle launch codes and military attack";
					"plans. You vaguely wonder how Goldilocks knows of such things.";
					+game.lose;
				}
			}
		
			if (you.eatenMatrix || you.weakened) {
				"Dreams come rapidly.  You hear those voices from earlier,";
				"`She managed to miss one of the devices, but one is enough.'";
				"Your last memory is a dream about missle launch codes and military attack";
				"plans. You vaguely wonder how Goldilocks knows of such things.";
				+game.lose;
			}
		
			" ";
			"You feel a sense of relief.  The pain is gone.";	
		
			move you from Bedroom to Cyber;
		}
	}
}

// this room makes me think of the Matrix, when Morpheus shows Neo the real world, 
// explains the Matrix, etc.
room Cyber {
	enter {
		" ";
		"You awake in a boundless grey space.  A sharp dressed man stands across from";
		"you.";
	}
	// there is nowhere to go.  This place is strange.
	(you,n) {
		"There is no direction in this place.  You feel your body moving, but you don't";
		"actually move.  The man still stands across from you.";
	}
	(you,e) {
		"There is no direction in this place.  You feel your body moving, but you don't";
		"actually move.  The man still stands across from you.";
	}
	(you,s) {
		"There is no direction in this place.  You feel your body moving, but you don't";
		"actually move.  The man still stands across from you.";
	}
	(you,w) {
		"There is no direction in this place.  You feel your body moving, but you don't";
		"actually move.  The man still stands across from you.";
	}
	(you, look) {
		"This really is a boundless space.  No wall or ceiling is visible, and there is";
		"no obvious light source. You're not even sure this is an actual PLACE.";
		" ";
		"The man regards you calmly, wondering if you'll talk.";
	}
	(you, talk) {
		"The man begins to speak, `This reality is being generated by your cybernetic";
		"implants. You are a trojan horse, dedicated to information espionage.";
		"Ask about your mission when you are ready.'";
	}
	(you, ask, mission) {
		"`Our enemies have a sophisticated method to detect our agents and hack";
		"their memories.  You contain a prototype chip giving only you the ability";
		"to resist and counterattack. You have done well to get this far, but you";
		"must retrieve their shield codes to be truly successful.'";
		" ";
		"`Open your eyes when you are ready to proceed.'";
	}
	// code clone to accomodate different input
	(you, ask) {
		"`Our enemies use hyperscape realities to manipulate our agents into revealing";
		"their secrets.  You contain a prototype chip giving only you the ability";
		"to resist and counterattack. You have done well to get this far, but now you";
		"must turn the tables.  You must retreive their quantum macguffin'";
		" ";
		"`Open your eyes when you are ready to proceed.'";
	}
	(you, open, eyes) {
		"Looking at the man, you ponder how one opens already open eyes.";
		"A never-before used implant chip suddenly flares into life, answering the";
		"question.";
		move you from Cyber to Lab;
	}
	// code clone to accomodate different input
	// you can shortcut this room by typing open in subsequent attempts.
	(you, open) {
		"Looking at the man, you ponder how one opens already open eyes.";
		"A never-before used implant chip suddenly flares into life, answering the";
		"question.";
		move you from Cyber to Lab;
	}
}

room Lab {
	state {focus}
	enter {
		" ";
		"Your *real* eyes open to find yourself in a lab.";
		-?Lab.focus;
	}
	// you can't move
	(you,n){
		"The straps hold you securely down";
	}
	(you,s){
		"The straps hold you securely down";
	}
	(you,e){
		"The straps hold you securely down";
	}
	(you,w){
		"The straps hold you securely down";
	}
	(you,look){
		"You realize that you are totally immobolized, lying down on a table.";
		"Neuronal Interface Units wind into your neck-port, connecting to your";
		"brain.  Across the room lies a man, similarly connected.";
		"Your cybernetics are overlaying a tremendous amount of data to read.";
	}
	(you, look, man) {
		"You look at the man.  His outfit suggests that he's a military doctor,";
		"but he's not on your side.  Involuntary motions suggest that he is in";
		"the cybertrance, as you just were.  He must be controlling the hyperscape.";
	}
	(you, read) {
		"CYBERNETIC DATA STREAM::SUBJECT CODENAME HELEN OF TROY";
		" - READ SITREP";
		" - READ VITALS";
		" - READ TACTICAL";
	}
	
	(you, read, sitrep) {
		"A printout starts flashing across the centre of your vision:";
		"<SITREP> THE DOCTOR IS ENGAGING YOU IN HIS HYPERSCAPE. HE IS ALSO CONNECTED,";
		"AND THUS VULNERABLE TO YOUR MENTAL ATTACKS.  HE IS UNAWARE OF YOUR AWAKENING";
		"<END>";
	}
	(you, read, vitals) {
		"A printout starts flashing across the centre of your vision:";
		"<VITALS> HEARTRATE 97, CORETEMP 98.6";
		"DANGER**TOXIN PRESENT**BODY PARALYZED <END>";
	}
	(you, read, tactical){
		"<TACTICAL> YOU MUST FIGHT THE DOCTOR. FIRST, FOCUS ON HIM";
		"NEXT, YOU MUST *SHIFT* AND ENGAGE HIM THROUGH THE CYBER LINK <END>";
	}
	(you, focus) {
		"You mentally focus, but you're not sure what you're focusing on.";
	}
	(you, focus, doctor) {
		"A double vision slides into focus.  While you can still see the lab,";
		"you can also see the doctor in the closet of the bedroom of the three";
		"bears, working intricate machinery.";
		+?Lab.focus;
	}
	(you, shift) {
		if (Lab.focus) {
			"The lab slides from view.  You are now fully in the hyperscape.";
			move you from Lab to Closet;
		}
		else {
			"Your cybernetics flare up, but you have no clear focus! Reality";
			"violently shifts.";
			move you from Lab to BearFight;
		}
	}
}
	
room Closet {
	state {shielded, images, power, victory}
	enter {
		" ";
		"The doctor sits at a console, struggling to control you and the";
		"hyperscape. He's mumbling something about bears when he notices you!";
		+?Closet.shielded;
		-?Closet.images;
		-?Closet.power;
		-?Closet.victory;
	}
	(you, look) {
		if (Closet.shielded) {
			"The closet isn't really a closet; it's more like a gymnasium.  You've";
			"seen enough hyperscapes to know that 1 + 1 doesn't always equal 2.";
			"The closet exit is to the north.";
			"The doctor is looking at you with a smirk.";
			"A powerful mental barrier separates the doctor from you.";
		}
		if (Closet.images) {
			"Dozens of doctors are preparing an attack. You need to find a way to";
			"isolate the real doctor before it's too late!";
			"The closet exit is to the north.";
		}
		if (Closet.power) {
			"The single doctor, now phase-isolated, is still preparing a deadly";
			"strike!  Your defenses cannot withstand an attack of that magnitude.";
			"The closet exit is to the north.";
		}
		if (Closet.victory) {
			"The doctor lies defeated before you.  The console beckons...";
			"The closet exit is to the north.";
		}
	}
	(you, n) {
		if (Closet!.victory) {
			"You try to flee back into the bedroom. The doctor, aware of your presence";
			"stymies your attempt with a neural phase eliminator.  This also stymies your";
			"effort to save your life...";
			+game.lose;
		}
		else {
			"And move away from the console?  No ma'am.";
		}
	}
	(you, talk) {
		if (Closet.shielded) {
			"`So, your faction has some new cybergear! Exciting! I can't wait to pull it";
			"from your corpse. You cannot defeat me when I control the hyperspace!'";
			" ";
			"Dozens of identical doctor-duplicas appear. All of them begin to focus on you,";
			"readying a attack. At the last moment, the doctor drops the barrier!  You have";
			"seconds to react!";
			-Closet.shielded;
			+Closet.images;
		}
		else {
			"No time for that now!";
		}
	}
	(you, use, spoon) {
		"Are you trying to get yourself killed?";
	}
	(you, use, matrix) {
		if (you !contains matrix) {
			"The matrix is busy containing the doctor.";
		}
		else {
			if (Closet.shielded) {
				"That barrier looks too strong.";
			}
			if (Closet.images) {
				"You cast the psycho-isolation matrix through the air.  With a bright pulse of";
				"light, it flares out the images and latches onto the real doctor!";
				"`Clever!  But I am still too strong for you!'";
				-Closet.images;
				+Closet.power;
				move matrix from you to offscreen;
			}
		}

	}
	(you, use, weakener) {
		if (you !contains weakener) {
			"The weakener has expended its charge.";
		}
		else {
			if (Closet.shielded) {
				"That barrier looks too strong.";
			}
			if (Closet.images) {
				"Activating the weakener, you think to cast it at a doctor-image!  Hesistation.";
				"Which doctor image?  You select one, hurl the device, but it's not the real";
				"doctor. The images laugh, and complete their dreadful attack...";
				+game.lose;
			}
			if (Closet.power) {
				"Activating the weakener, you mentally direct it to the doctor.  It pulses a";
				"deep violet, and drops the doctor to the floor!  He is now too weak to fight.";
				-Closet.power;
				+Closet.victory;
				move weakener from you to offscreen;
			}
		}
	}
	(you, use, console) {
		if (Closet.victory) {
			"You sit down at the console. The machinery here, working with your cybernetics,";
			"will allow you to reverse the hyperscape and control the doctor! Working";
			"quickly you manage to invade the Doctor's pysche...another shift.";
			" ";
			move you from Closet to DoctorScape;

			// some inventory gymnastics.  You're done in the hyperscape, so
			// hyperscape objects are now meaningless.
			move spoon from you to offscreen;
			if (you contains bowl) {
				move bowl from you to offscreen;
			}
			if (you contains chairleg) {
				move chairleg from you to offscreen;
			}
		}
		else {
			"Like the Doctor will let you.";
		}
	}
	(you, shift) {
		"You shift back into the lab. You awake, only to find that the Doctor shifted ";
		"faster and is standing over with a gun. Strapped down and paralyzed,";
		"you can only watch...";
		+game.lose;
	}
}

// this room is my personal favorite, but it can be entirely skipped if one focuses on
// the Doctor before shifting.  
room BearFight {
	state {angryBears}
	enter {
		" ";
		"Everything blacks out for a second, but you quickly regain your senses.";
		"You conclude the Doctor controlled your shift due to a lack of focus.";
		"While this looks like the bedroom from before, there are three large";
		"differences: three very angry bears are now here.";
		+?BearFight.angryBears;
	}
	(you, look) {
		if (BearFight.angryBears) {
			"This seems like the bedroom from earlier, but with three large differences:";
			"bears. Three very angry bears.";
		}
		else {
			"The bears are now gone!  The way south to the closet and the doctor is free.";
		}
	}
	(you, s) {
		if (BearFight.angryBears) {
			"Through the bears?  Not likely.";
		}
		else {
			"You proceed into the closet.";
			move you from BearFight to Closet;
		}
	}
	(you, d) {
		if (BearFight.angryBears) {
			"Through the bears?  Not likely.";
		}
		else {
			"That's where the bears went. You don't want to face them again.";
		}
	}
	(you, use, chairleg) {
		"Roaring with anger, you smash a bear in the nose with the chairleg.";
		"Startled by your ferocity, the bears retreat down the stairs!";
		-?BearFight.angryBears;
	}
	(you, use, bowl) {
		if (BearFight.angryBears) {
			"You whip the bowl at a bear, but miss.  Unfortunately the bears do not miss";
			"when they come at you...";
			+game.lose;
		}
		else {
			"And do what with it?";
		}
	}
	(you, use, spoon) {
		if (BearFight.angryBears) {
			"A battle cry: `Spoon!'.  Your intensity is palpable, but unfortunately, a spoon";
			"cannot harm a bear.  The bears can, however, harm you, which they proceed to do.";
			+game.lose;
		}
		else {
			"And do what with it?";
		}
	}
	(you, shift) {
		"Thinking quickly, you activate your cybernetics and shift.";
		move you from BearFight to Lab;
	}
}

room DoctorScape {
	state {free}
	enter {
		"This is the lab from before.";
	}
	(you, look) {
		if (DoctorScape.free) {
			"Your body lies across the room, waiting to be freed.";
		}
		else {
			"You look across the lab to see your own body strapped down.";
			"Looking down, you see that your hack has worked.  You're in the";
			"Doctor's body!  This is the ultimate disguise.";
			"A door to the east leads to the rest of the facility.";
		}
		if (DoctorScape contains gun) {
			"There is a gun on the table beside you.";
		}
		if (DoctorScape contains keys) {
			"The keys for your straps sit on the workbench.";
		}
		if (DoctorScape contains clipboard) {
			"There is an empty clipboard on the shelf.";
		}
		if (DoctorScape contains antidote) {
			"Beside your body sits the antidote for your induced paralysis.";
		}	
	}
	(you, take, gun) {
		if (DoctorScape contains gun) {
			"Doctor-you grabs the gun. This is the real world, and there might be shooting.";
			move gun from DoctorScape to you;
			+?Escape.armed;
		}
		else {
			"You already have that.";
		}
	}
	(you, take, keys) {
		if (DoctorScape contains keys) {
			"Doctor-you picks up the keys. Now you can release...you.";
			move keys from DoctorScape to you;
		}
		else {
			"You already have that.";
		}
	}
	(you, take, clipboard) {
		if (DoctorScape contains clipboard) {
			"A clipboard! Walk quickly and carry a clipboard, and no one will question you.";
			move clipboard from DoctorScape to you;
		}
		else {
			"You already have that.";
		}
	}
	(you, take, antidote) {
		if (DoctorScape contains antidote) {
			"Adminstering this will fix up your (actual) body.";
			move antidote from DoctorScape to you;
		}
		else {
			"You already have that.";
		}
	}
	(you, look, body) {
		if (DoctorScape.free) {
			"Your body is strapped down securely. You'll need to free it.";
		}
		else {
			"You have the perfect disguise. Maybe now is the time to search the";
			"facility?  Your strapped down body isn't going anywhere.";
		}
	}
	(you,shift) {
		"You have the perfect disguise. Maybe now is the time to search the";
		"facility?";
	}
	(you, e) {
		"You confidently stride through the enemy facility.  With your doctor-body";
		"no one suspects a thing as you search for your prize.";
		move you from DoctorScape to InnerSanctum;
	}

	(you, free) {
		if (DoctorScape!.free) {
			"You should explore the facility first.";
		}
		else {
			if (you contains antidote && you contains keys) {
				"You quickly get to work, adminstering the antidote, and unlocking the straps.";
				"With a momentary focus, you shift back to your body.";
				
				// inventory gymnastics. As one can imagine, 
				// changing bodies changes your accordingly.
				
				move antidote from you to offscreen;
				move keys from you to offscreen;
				move macguffin from you to Escape;
				if (you contains gun) {
					move gun from you to offscreen;
				}
				else {
					move gun from DoctorScape to Escape;
				}
				if (you contains clipboard) {
					move clipboard from you to Escape;
				}
				else {
					move clipboard from DoctorScape to Escape;
				}				
				move you from DoctorScape to Escape;
			}
			else {
				"You need both the keys and the antidote to do this.";
			}
		}
	}
	// code clone of (you, free) to accomodate different input
	(you, free, body) {
		if (DoctorScape!.free) {
			"You should explore the facility first.";
		}
		else {
			if (you contains antidote && you contains keys) {
				"You quickly get to work, adminstering the antidote, and unlocking the straps.";
				"With a momentary focus, you shift back to your body.";
				
				// inventory gymnastics. As one can imagine, 
				// changing bodies changes your accordingly. 
				
				move antidote from you to offscreen;
				move keys from you to offscreen;
				move macguffin from you to Escape;
				if (you contains gun) {
					move gun from you to offscreen;
				}
				else {
					move gun from DoctorScape to Escape;
				}
				if (you contains clipboard) {
					move clipboard from you to Escape;
				}
				else {
					move clipboard from DoctorScape to Escape;
				}				
				move you from DoctorScape to Escape;
			}
			else {
				"You need both the keys and the antidote to do this.";
			}
		}
	}	
}

room InnerSanctum {
	enter {
		"The world's first skin-spy walks into the design lab unfettered.";
	}
	(you, look) {
		if (InnerSanctum contains macguffin) {
			"There it is...the Quantum Macguffin...";
		}
		else {
			"There's nothing else here.  Only the exit to the east.";
		}
	}
	(you, e) {
		if (InnerSanctum contains macguffin) {
			"Aren't you forgetting something?  Something important? Like the";
			"macguffin?";
		}
		else {
			"You calmly walk out.  No one suspects a thing.";
			move you from InnerSanctum to DoctorScape;
		}
	}
	(you, take, macguffin) {
		if (InnerSanctum contains macguffin) {
			"Carefully, you grab the Quantum MacGuffin.  The other researchers";
			"barely spare a glance at you, their long-time associate.";
			move macguffin from InnerSanctum to you;
			+?DoctorScape.free;		
		}
		else {
			"You double-check.  Yes, you do in fact carry the Quantum Macguffin";
		}
	}
}

room Escape {
	state {armed}
	enter {
		"You open your own eyes, and find yourself staring at the ceiling of the";
		"lab.  You're getting sick of this place.";
	}
	(you, look) {
		if (you contains macguffin) {
			"The door to the east beckons.";
		}
		if (Escape contains macguffin) {
			"The doctor is crumpled on the floor in front of you, but he's starting to stir.";
			"The macguffin is clutched in one of the doctor's hands";
		
			if (Escape contains gun) {
				"There is a gun on the table beside you.";
			}
			else {
				"Unfortunately, the doctor's other hand contains a gun. The one you picked up.";
			}
			if (Escape contains clipboard) {
				"There is an empty clipboard on the shelf.";
			}
		}
	}
	(you, take, gun) {
		if (Escape.armed) {
			"You wrestle away the gun before the doctor is fully concious.";
			-Escape.armed;
			move gun from offscreen to you;
		}
		if (Escape contains gun) {
			"You grab the gun";
			move gun from Escape to you;
		}
	}
	(you, take, macguffin) {
		if (Escape.armed) {
			"You reach out and quickly grab the macguffin before the doctor can react.";
			"Unfortunately, he's still got that gun.  When he finally does react, it's not";
			"good for you...not good at all.";
			+game.lose;
		}
		else {
			if (Escape contains macguffin) {
				"You seize the macguffin from the Doctor's hands! An overlay flares into life";
				"MISSION ACCOMPLISHED: SENDING EXTRACTION SQUAD";
				"MOVE TO ROOF <END>";
				move macguffin from Escape to you;
			}
			else {
				"You already have it!  Move to the roof!";
			}
		}
	}	
	(you, e) {
		if (you contains macguffin) {
			"You sneak out into the hallway. Already, the sounds of explosions are rocking";
			"the facility. This is a major assault by your faction, with the sole goal of";
			"freeing you and the MacGuffin. Through the confusion, you slink unnoticed to a";
			"back staircase.";
			" ";
			"Opening the door to the roof, you emerge to find Cyberlord Aleph himself.";
			"`Do you have the Quantum MacGuffin?', he demands.";
			" ";
			"`Yes sir!', you report";
			" ";
			"`Excellent. You have preserved the life of the Federation and our very";
			"existence. Your rewards will be priceless.'  The Cyberlord, Spymaster of";
			"the Federation, actually smiling, continues, 'Now get to the";
			"chopper if you want to live!'";
			+game.win;
		}
		else {
			"Shouldn't you get the macguffin first?";
		}
	}
}

object keys {
}
object antidote {
}
object clipboard {
	// no effect on the game
}
object macguffin {
}
object gun {
}
object matrix {
	state {porridge}
}
object weakener {
	state {chair}
}
object bowl {
	// no effect on the game
	state {used}
}
object spoon {
}
object chairleg {
}

start {
	move you from offscreen to Outside;
	move spoon from offscreen to Kitchen;
	move bowl from offscreen to Kitchen;
	+?bowl.used;
	move matrix from offscreen to Kitchen;
	+?matrix.porridge;
	move weakener from offscreen to LivingRoom;
	+?weakener.chair;
	+you.outside;
	move keys from offscreen to DoctorScape;
	move antidote from offscreen to DoctorScape;
	move clipboard from offscreen to DoctorScape;
	move gun from offscreen to DoctorScape;
	-?DoctorScape.free;
	move macguffin from offscreen to InnerSanctum;
	-?Escape.armed;
	"You find yourself standing on the porch of a lovely house deep in the woods.";
}

// this method executes after every command.  If you performed an action that
// resisted, or if you were resisting but stopped, then this method increments
// or resets the counter accordingly, and displays a message as feedback.
// If you resist too much, it kills you.
// The messages are meant to reflect the Doctor's efforts to get you on track, as
// well as to tell the user how to avoid death.

thread() {
	if (you.resetResist) {
		-you.resetResist;
		if (you.resist > 0) {
			" ";
			"You feel a sense of relief.  The pain is gone.";		
			you.resist = 0;
		}
	}
	if (you.resisted) {
		-you.resisted;
		you.resist++;
		" ";
		if (you.resist == 1) {		
			"You feel a disconcerting itch in the back of your neck.";
		}
		if (you.resist == 2) {
			"The itch has matured to a searing pain. Something is amiss.";
			"Half-heard (imagined?) voices seem to intrude on your senses.";
		}
		if (you.resist == 3) {
			"As the pain continues to grow, you clearly hear a distant voice. `Her";
			"cybernetics have activated! This resistance is dangerous for us, get her";
			"back on the story or we risk everything!";
			
			if (you.outside) {
				" ";
				"The door seems to grow even more welcoming. You have a powerful urge to";
				"go inside.";
			}
			if (you.porridge) {
				" ";
				"The porridge smells incredible.  You find yourself salivating in";
				"anticipation.";
			}
			
			if (you.chairs) {
				" ";
				"You have a strong urge to sit down and relax for a spell.";
			}
			
			if (you.beds) {
				" ";
				"Your fatigue is overwhelming.  You simply must lay down and sleep.";
			}
			
		}
		if (you.resist == 4) {
			"That voice again: `She is resisting your hyperscape. We cannot risk her";
			"awakening. Terminate the experiment...and terminate her.'  The house, and";
			"everything else, fades away into blackness...";
			+game.lose;
		}
	}
}

(you, i) {

	// when you're shifted to the lab in Act II, you have nothing.
	if (Lab contains you || Cyber contains you) {
		"There's nothing but you, strapped to a table.";
	}
	else {
		if (you contains matrix) {
			"You are carrying a psycho-isolation matrix";
		}
		if (you contains spoon) {
			"You are carrying a spoon.";
		}
		if (you contains bowl) {
			"You are carrying a dirty bowl.";
		}
		if (you contains chairleg) {
			"You are carrying a chairleg.";
		}
		if (you contains weakener) {
			"You are carrying a psionic weakener.";
		}
		if (you contains gun) {
			"You are carrying a gun.";
		}
		if (you contains antidote) {
			"You are carrying the antidote.";
		}
		if (you contains keys) {
			"You are carrying the keys to your straps.";
		}
		if (you contains clipboard) {
			"You are carrying a clipboard and look very important.";
		}
		if (you contains macguffin) {
			"You are carrying the Quantum MacGuffin.";
		}
	}
}